8.4 Datatypes and Serialization

Prefab structure types (see Prefab Structure Types ) automatically support serialization: they can be written to an output stream, and a copy can be read back in from an input stream:

> (define-values (in out) (make-pipe))

> (write #s(sprout bean) out)

> (read in)

'#s(sprout bean)

Other structure types created by struct, which offer more abstraction than prefab structure types, normally write either using #<....> notation (for opaque structure types) or using #(....) vector notation (for transparent structure types). In neither case can the result be read back in as an instance of the structure type:

> (struct posn (x y))

> (write (posn 1 2))

#<posn>

> (define-values (in out) (make-pipe))

> (write (posn 1 2) out)

> (read in)

pipe::1: read: bad syntax `#<`

> (struct posn (x y) #:transparent)

> (write (posn 1 2))

#(struct:posn 1 2)

> (define-values (in out) (make-pipe))

> (write (posn 1 2) out)

> (define v (read in))

> v

'#(struct:posn 1 2)

> (posn? v)

#f

> (vector? v)

#t

The serializable-struct form defines a structure type that can be serialized to a value that can be printed using write and restored via read. The serialized result can be deserialized to get back an instance of the original structure type. The serialization form and functions are provided by the racket/serialize library.

In addition to the names bound by struct, serializable-struct binds an identifier with deserialization information, and it automatically provides the deserialization identifier from a module context. This deserialization identifier is accessed reflectively when a value is deserialized.