» azurerm_mysql_configuration

Sets a MySQL Configuration value on a MySQL Server.

» Example Usage

resource "azurerm_resource_group" "test" {
  name     = "api-rg-pro"
  location = "West Europe"
}

resource "azurerm_mysql_server" "test" {
  name                = "mysql-server-1"
  location            = "${azurerm_resource_group.test.location}"
  resource_group_name = "${azurerm_resource_group.test.name}"

  sku {
    name     = "B_Gen5_2"
    capacity = 2
    tier     = "Basic"
    family   = "Gen4"
  }

  storage_profile {
    storage_mb            = 5120
    backup_retention_days = 7
    geo_redundant_backup  = "Disabled"
  }

  administrator_login          = "psqladminun"
  administrator_login_password = "H@Sh1CoR3!"
  version                      = "5.7"
  ssl_enforcement              = "Enabled"
}

resource "azurerm_mysql_configuration" "test" {
  name                = "interactive_timeout"
  resource_group_name = "${azurerm_resource_group.test.name}"
  server_name         = "${azurerm_mysql_server.test.name}"
  value               = "600"
}

» Argument Reference

The following arguments are supported:

name - (Required) Specifies the name of the MySQL Configuration, which needs to be a valid MySQL configuration name. Changing this forces a new resource to be created.
server_name - (Required) Specifies the name of the MySQL Server. Changing this forces a new resource to be created.
resource_group_name - (Required) The name of the resource group in which the MySQL Server exists. Changing this forces a new resource to be created.
value - (Required) Specifies the value of the MySQL Configuration. See the MySQL documentation for valid values.

» Attributes Reference

The following attributes are exported:

id - The ID of the MySQL Configuration.

» Import

MySQL Configurations can be imported using the resource id, e.g.

terraform import azurerm_mysql_configuration.interactive_timeout /subscriptions/00000000-0000-0000-0000-000000000000/resourceGroups/mygroup1/providers/Microsoft.DBforMySQL/servers/server1/configurations/interactive_timeout